COMMENT ⊗   VALID 00007 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	% This file contains special letters and letter combinations,
C00003 00003	"Dotless italic letter i"
C00004 00004	"Dotless italic letter j"
C00005 00005	"Italic German letter ss"
C00008 00006	"Italic ligature ae"
C00010 00007	"Italic ligature oe"
C00012 ENDMK
C⊗;
% This file contains special letters and letter combinations,
% compatible with the alphabet ``itall''.
% Codes \¬013, \¬014, \¬033--\¬035 are used.
"Dotless italic letter i";
call charbegin('013,7,1-fixwidth,1-fixwidth,px,0,0);
x1=.5r+.25u; x2=.5r-.25u;
call `a skewentry(u,1);	% opening hook
call `b skewexit(2,r-u);	% closing hook
hpen; w1 draw 1..2.	% stem
"Dotless italic letter j";
call charbegin('014,8,1-fixwidth,1-fixwidth,px,pd,0);
cpen; lft3x1=lft0x2=round .5u; x3=2.5u; x4=x5=good1 .5(r+u);
bot3y1=-.9d; y2=y1; bot6y3=-d-oo; bot6y4=-1/3d;
w3 draw 1;	% bulb
call `a entry(u,5);	% opening hook
hpen; draw |w1|5..|w1#|4{0,-1}..|w0#|3{-1,0}..2{0,1}.	% stem and tail
"Italic German letter ss";
call charbegin('033,11,1-fixwidth,0,ph,pd,(ph-2/3pd).slant-1.5pu);
cpen; lft3x1=lft0x2=round .75u; x3=2.25u;
x90=3u; x91=4u; y90=y6; y91=y3;	% (the line of slant will be $90\to91$)
x20=.8[x6+x5-x90,x90]; x21=.8[x3+x4-x91,x91]; y20=.8[y5,y90]; y21=.8[y4,y91];
x6=.5[x5,x7]; rt1x7=round(r-2u); x8=.6[x9,x7]; rt10x9=round(r-3.5u);
x10=.5[x9,x11]; rt2x11=round(r-u); x12=x10-u;
bot3y1=-.85d; y1=y2; bot6y3=-d-oo; y4=e; y5=.25[m,h];
top6y6=h+oo; y7=.5[m,h]; y8=.6[y7,y9]; y9=.5[e,m]; y10=.5[y9,y11];
new aa,bb; y5=aa[y90,y91]; x5=aa[x90,x91]; x4=bb[x90,x91]; y4=bb[y90,y91];
y11=.5e; bot6y12=-oo; y13=y14; bot3y14=.125e; lft0x13=lft3x14=round(rt1x4+.5u);
w3 draw 1; draw 14;	% bulbs
hpen; draw |w0|2{0,-1}..|w0#|3{1,0}..|.5[w0,w1]|21{x4-x3,y4-y3}..
	|w1#|4{x5-x4,y5-y4}..|w1#|5{x5-x4,y5-y4}..
	|.5[w0,w1]|20{x6-x5,y6-y5}..|w0#|6{1,0}..|w1#|7{0,-1}..
	|w10#|8{1.5(x9-x8),y9-y8}..|.25[w10,w2]|9{0,-1}..
	|.75[w10,w2]|10{2(x10-x9),y10-y9}..|w2#|11{0,-1}..
	|w0#|12{-1,0}..13{0,1};	% stroke
if lcs≠0: new aa; x19=aa[x4,x5]; y19=aa[y4,y5]; top0y19=m;
	call `a serif(19,1,4,-lcs);	% spur
fi.
"Italic ligature ae";
call charbegin('034,13,0,0,px,0,0);
new w99; w99=round .75[w0,w1];
hpen; rt11x1=round(r-1.5u); x2=good99 .5r;
x3=x4=.5(r+6u); rt0x5=r-.5u; x6=x5; x20=rt99x2;
y1=.5[y2,y3]; y2=e; top0y3=m+oo; bot0y4=-oo; top0y5=.5e; y6=y20=e;
w11 draw 2..20{1,0}..1{0,1}..3{-1,0};	% bar and shoulder
call `a arc(3,2,w99); call `b arc(4,2,w99);	% right bowl
draw 4{1,0}..5(..6);	% point
x7=x2; x8=good2 1.5u; top0y7=m; y8=.3[y9,y7];
x9=.5[x8,x2]; bot0y9=-oo;
draw |w0#|7{3(x8-x7),y8-y7}..|w2#|8{0,-1};
call `c arc(9,8,w2); call `d arc(9,2,w0);	% bottom of left bowl
cpen; x10=x11=x2; top99y10=m+oo; bot99y11=-oo;
w99 draw 10..11.	% stem
"Italic ligature oe";
call charbegin('035,13,0,0,px,0,0);
hpen; rt11x1=round(r-1.5u); x2=good2 .5r;
x3=x4=.5(r+6u); rt0x5=r-.5u; x6=x5; x20=rt2x2;
y1=.5[y2,y3]; y2=e; top0y3=m+oo; bot0y4=-oo; top0y5=.5e; y6=y20=e;
w11 draw 2..20{1,0}..1{0,1}..3{-1,0};	% bar and shoulder
call `a arc(3,2,w2); call `b arc(4,2,w2);	% right bowl
draw 4{1,0}..5(..6);	% point
x7=.5[x8,x9]; x8=good2 1.5u; x9=x2; y7=y3; y8=y9=y4;
call `c darc(7,8,w2); call `d darc(7,9,w2).	% left bowl